0 BEGIN PGM probe1 MM
1 BLK FORM 0.1 Z X+0 Y+0 Z+0
2 BLK FORM 0.2 X+0 Y+0 Z+0
3 M140 MB MAX
4 TOOL CALL 11 Z
5 CYCL DEF 247 DATUM SETTING ~
Q339=+15 ;DATUM NUMBER
6 PLANE VECTOR BX+0 BY+0 BZ+1 NX-1 NY+0 NZ+0 TURN FMAX SEQ- TABLE ROT
7 L X-5 Y-45 Z+60 R0 FMAX
8 TCH PROBE 0.0 REF. PLANE Q1991 Z- ;第一点测量写入Q1991
9 TCH PROBE 0.1 X-5 Y-45 Z+0
10 L X-5 Y+45 Z+60 R0 FMAX
11 TCH PROBE 0.0 REF. PLANE Q1992 Z-;第二点测量写入Q1992
12 TCH PROBE 0.1 X-5 Y+45 Z+0
13 M140 MB MAX
14 PLANE RESET STAY
15 L Z+0 R0 FMAX M91
16 L B+0 X+0 R0 FMAX M91
17 Q1993 = Q1992 - Q1991 ;第二点减去第一点的差值写入Q1993 (测量点位顺序从负往正)
18 Q1994 = ATAN ( Q1993 / 90 ) ;计算旋转角度写入到Q1994
19 L C+Q1994 R0 FMAX
20 FN 18: SYSREAD Q1995 = ID503 NR15 IDX6 ;读取预设表第15号第六列（C轴）的数据到Q1995
21 Q1996 = Q1995 - Q1994 ;计算要写入到预设表的值
22 Q1997 = Q1995 - Q1994 - 90
23 Q1998 = Q1995 - Q1994 - 270
24 FN 17: SYSWRITE ID 503 NR15 IDX6 =+Q1996 ;把Q1996写入预设表第15号第六列格子
25 FN 17: SYSWRITE ID 503 NR16 IDX6 =+Q1997
26 FN 17: SYSWRITE ID 503 NR17 IDX6 =+Q1998
27 CYCL DEF 247 DATUM SETTING ~
Q339=+15 ;DATUM NUMBER ;生效15号预设表
28 M126
29 L X+0 Y+0 C+0 R0 FMAX
30 CYCL DEF 247 DATUM SETTING ~
Q339=+16 ;DATUM NUMBER
31 L X+0 Y+0 C+0 R0 FMAX
32 CYCL DEF 247 DATUM SETTING ~
Q339=+17 ;DATUM NUMBER
33 L X+0 Y+0 C+0 R0 FMAX
34 M0
35 L Z-5 R0 FMAX
36 TCH PROBE 412 DATUM INSIDE CIRCLE ~
Q321=+0 ;CENTER IN 1ST AXIS ~
Q322=+0 ;CENTER IN 2ND AXIS ~
Q262=+54 ;NOMINAL DIAMETER ~
Q325=+0 ;STARTING ANGLE ~
Q247=+90 ;STEPPING ANGLE ~
Q261=-5 ;MEASURING HEIGHT ~
Q320=+0 ;SET-UP CLEARANCE ~
Q260=+100 ;CLEARANCE HEIGHT ~
Q301=+1 ;MOVE TO CLEARANCE ~
Q305=+1 ;NUMBER IN TABLE ~
Q331=+0 ;DATUM ~
Q332=+0 ;DATUM ~
Q303=+1 ;MEAS. VALUE TRANSFER ~
Q381=+0 ;PROBE IN TS AXIS ~
Q382=+0 ;1ST CO. FOR TS AXIS ~
Q383=+0 ;2ND CO. FOR TS AXIS ~
Q384=+0 ;3RD CO. FOR TS AXIS ~
Q333=+0 ;DATUM ~
Q423=+4 ;NO. OF MEAS. POINTS ~
Q365=+0 ;TYPE OF TRAVERSE
37 M140 MB MAX
38 L X+0 Y+0 R0 FMAX M91
39 END PGM probe1 MM